type Middleware

Wraps a request: runs code before and/or after next(req), may change the request it passes on or the reply it returns, or answers by itself without calling next (short-circuit). Router.layer adds one around the whole router (404/405 included).

Example:

oxl✓ проверяется в CI

use std.http { Server, ServerConfig, ServerHandle, Router, Request, Reply, Client, Header, HttpConfig, Response, Middleware, Next, withMiddleware, requireHeader, logRequests, timing, WebSocket, WsConfig, SseWriter, BodyWriter, chunks }

fn body(req: Request) -> str {
  match req.text() {
    str t => t
    DecodeError _ => ""
  }
}

fn run() -> () | NetError | DecodeError | Panicked  net, io, time {
  let srv = Server.bind(ServerConfig{ port: 0, followNode: false })?
  defer srv.close()
  let stop = srv.handle()
  let base = "http://127.0.0.1:{srv.port()}"
  let auth: Middleware = (req: Request, next: Next) => {
    if req.header("x-token") == none { return Reply.text("login first", 401) }
    next(req)
  }
  let router = Router.new().get("/secret", (req: Request) => Reply.text("42")).layer(auth)
  scope {
    spawn stop.serve(router)
    print((Client.get("{base}/secret")?).status)
    print((Client.get("{base}/secret", [Header{ name: "X-Token", value: "t" }])?).text()?)
    stop.shutdown()
    ()
  }?
}

fn main() io, net, time {
  match run() {
    NetError _ => print("net error")
    DecodeError _ => print("decode error")
    Panicked _ => print("panicked")
    _ => {}
  }
}

Вывод

401
42

pub(api) type Middleware = fn(Request, Next) -> Reply net, io, time escaping

С версии. 1.0.0-beta

Определено в: std/http/http.oxl:3086

См. также

std.http