OxL Reference
EnglishРусский

data BodyWriter

Writer of a streamed response body (Reply.stream). Each write is sent at once as one chunk.

Example:

oxl✓ checked in CI
use std.http { Server, ServerConfig, ServerHandle, Router, Request, Reply, Client, Header, HttpConfig, Response, Middleware, Next, withMiddleware, requireHeader, logRequests, timing, WebSocket, WsConfig, SseWriter, BodyWriter, chunks }

fn body(req: Request) -> str {
  match req.text() {
    str t => t
    DecodeError _ => ""
  }
}

fn run() -> () | NetError | DecodeError | Panicked  net, io, time {
  let srv = Server.bind(ServerConfig{ port: 0, followNode: false })?
  defer srv.close()
  let stop = srv.handle()
  let base = "http://127.0.0.1:{srv.port()}"
  let router = Router.new().get("/count", (req: Request) => Reply.stream("text/plain", (w: BodyWriter) => {
    w.writeText("1,")?
    w.writeText("2,")?
    w.write(Utf8.encode("3"))?
  }))
  scope {
    spawn stop.serve(router)
    print((Client.get("{base}/count")?).text()?)
    stop.shutdown()
    ()
  }?
}

fn main() io, net, time {
  match run() {
    NetError _ => print("net error")
    DecodeError _ => print("decode error")
    Panicked _ => print("panicked")
    _ => {}
  }
}
Output
1,2,3
pub(api) data BodyWriter

Thread safety. owned by the producer task of the reply.

Since. 1.0.0-beta

Methods

write(payload: bytes) -> () | NetError net
Sends payload as one chunk of the response body.
writeText(text: str) -> () | NetError net
Sends text (UTF-8) as one chunk of the response body.

Defined in: std/http/http.oxl:1747

See also